{As} actionscript.gen.tr » Döngüler

XML Kullanarak Dinamik Rotator Yapımı

Erol Demirer — Sun, 21 Nov 2010 10:49:25 +0000

Bu uygulamamızda XML tabanlı dinamik banner rotator yapacağız. Uygulamanın bitmiş hali yukarıda görmüş olduğunuz gibi. Uygulama için ilk olarak Rotator isminde bir klasör oluşturalım. Klasörü oluşturduktan sonra 625 x 325 piksel boyutlarında yeni bir belge açalım ve klasörün içerisine BannerRotator ismi ile kaydedelim. Belgenin arka plan rengi #333333 olsun. Rotatör isimli klasörün içerisine data ve images isimli iki klasör oluşturalım. XML dosyamızı data klasorunun içerisine, imajlarıda images klasörünün içerisine kaydedeceğiz. Klasör yapısının aşağıdaki gibi olması gerekmektedir.

İlk olarak XML dosyamızı oluşturup data.xml adı ile data klasörünün içerisine kaydedelim. XML belgesinin içeriği aşağıdaki gibidir.İmajların adres bilgileri için path, imajlara tıklandığında açılacak sayfaların adresleri içinde link niteliklerini(Attribute) kullanacağız. İmages klasörünün içerisine de kullanacağımız imajları kaydedelim. Kullanacağımız imajların boyutlarını da 575 x 275 piksel olarak ayarlayalım.

<images>

<image path="images/image1.jpg" link="http://actionscript.gen.tr"/>
<image path="images/image2.jpg" link="http://actionscript.gen.tr"/>
<image path="images/image3.jpg" link="http://actionscript.gen.tr" />
<image path="images/image4.jpg" link="http://actionscript.gen.tr"/>
<image path="images/image5.jpg" link="http://actionscript.gen.tr"/>
<image path="images/image6.jpg" link="http://actionscript.gen.tr"/>

images>

Şimdi Flash belgemize geri dönelim. Uygulama içerisinde kullacağımız butonları hazırlayalım. İmajlar arasında ileri geri hareket edebilmek için iki tane, toplam imaj sayısını gösterebilmek içinde 1 tane olmak üzere toplamda 3 butona ihtiyacımız olacak. Butonlar MovieClip sembolü olarak hazırlamamız gerekiyor. Ayrıca tüm butonların içlerinde birer tane dinamik text alanı olması gerekiyor. Dinamik text alanlarının isimleri aşağıdaki gibidir. MovieClipleri oluştururken ileri gitmek için kullanacağımız butonun ismini Next, geri gitmek için kullanacağımız butonun ismini Previous, sayıları göstermek için kulanacağımız butonun ismini de Selector olarak değiştirelim ve Convert to Symbol penceresindeki Advanced ikonuna tıklayalım ve açılan bölüme Export for ActionScript seçeneğini işaretleyelim. Bu seçeneği işaretledikten sonra Class sekmesinde yukarıda belirttiğim isimler yoksa düzeltelim ve Ok butonuna tıklayarak pencereyi kapatalım. Selector isimli MovieClip’in içerisindeki text alanının renginide #333333 olarak değiştirelim.

Yüklenen imaj sayısını kullanıcıya bildirmek içinde bir Preloader kullanacağız. Sahne boyutlarında bir dikdörtgen çizelim. Rengi #99999 ve Alpha değeri %50 olsun. Dikdörtgeni seçelim ve MovieClip olarak sembole dönüştürelim. Convert to Symbol panelinde ismini Preloader olarak değiştirelim ve pencereyi kapatalım. Instance Name kısmına preloader_mc yazalım. Sonrada çift tıklayarak sembolün içerisine girelim ve sembolün içerisine dinamik bir text alanı ekleyelim. Text alanının isminde load_txt olsun.

MovieClipleri hazırladığımıza göre kodları yazmaya başlayabiliriz. İlk olarak varsa sahne üzerinde bulunan sembolleri temizleyelim ve Actions panelini açalım. İlk olarak XML dosyasındaki verileri yüklemek için URLLoader nesnesi t tanımlayacağız.

var xmlLoader:URLLoader=new URLLoader();
xmlLoader.load(new URLRequest("data/data.xml"));

Sonrada uygulama içerisinde kullanacağımız değişkenleri tanımlayacağız. xmlData nesnesi XML dosyasındaki tüm datayı, xmlList nesnesi ise images tagları içerisindeki bilgiyi içerisinde tutacak. imageLoader nesnesini imajları yüklemek için kullanacağız. loaded değişkeni ile yüklenen imaj sayısını, howImage değişkeni ile hangi imajın görüntülendiğini, imageWidth değişkeni ile de imajların genişlik değeri bilgilerini saklayacağız.

var xmlData:XML;
var xmlList:XMLList;
var imageLoader:Loader;
var loaded:int = 0;
var howImage:int;
var imageWidth:int;

Şimdi de uygulama içerisinde kullanacağımız MovieClipleri tanımlıyoruz. maskMC ile imajları maskeleme işlemini gerçekleştireceğiz. holderMC ve imageHolderMC MovieClipler’i sadece imajları taşıma işlemi yapacak. Son olarakta oluşturduğumuz MovieClip’leri uygulama içerisine dahil ediyoruz.

var maskMC:MovieClip=new MovieClip();
maskMC.graphics.beginFill(0x000000);
maskMC.graphics.drawRect(25,25,575,275);
maskMC.graphics.endFill();
addChild(maskMC);
var holderMC:MovieClip;
var imageHolderMC:MovieClip;
var selectorMC:MovieClip;

var nextButton:Next;
var prevButton:Previous;
var selector:Selector;

Üç tane dizi tanımlaması yapıyoruz. imagePosition dizisine imajların x konumlarını, images dizisine imajları taşıyacak MovieClipleri, selectors dizisine ise imaj sayısına göre oluşturulacak butonları ekleyeceğiz.

var imagePosition:Array=new Array();
var images:Array=new Array();
var selectors:Array=new Array();

Geçişlerin belirlediğimiz süre bitiminde otomatik olarak yapılması için bir Timer nesnesi tanımlıyoruz ve süreyi 5 saniye olrak ayarlayoruz.

var transitionsTimer:Timer = new Timer(1000 * 5);

Kullanacağımız nesne ve değişkenleri tanımladıktan sonra xmlLoader nesnesine bir olay dinleyici ekleyerek yükleme işleminin bitişini kontrol edeceğiz. Fonksiyon içerisinde de kullanacağımız değişken ve nesnelere değer atamalarını yapacağız. holderMC isimli MovieClip tüm imajları içerisinde taşıyacak. maskMC ile de maskeleme işlemini gerçekleştireceğiz. imageLoader nesnesine olay dinleyici ekleyerek yükleme işlemi bittiğinde bir sonraki imajın yüklenmesini sağlayacağız. Preloader_mc içerisindeki text alanına da toplam imaj sayısını ve bu imajların kaç tanesinin yüklendiğini yazdıracağız

xmlLoader.addEventListener(Event.COMPLETE, xmlLoaded);

function xmlLoaded(e:Event)
{
xmlData = new XML(e.target.data);
xmlList = new XMLList(xmlData.children());

imageLoader=new Loader();
holderMC=new MovieClip();
imageHolderMC=new MovieClip();
addChild(holderMC);
holderMC.x = 25;
holderMC.y = 25;
maskMC.cacheAsBitmap = true;
holderMC.cacheAsBitmap = true;
holderMC.mask = maskMC;

imageHolderMC.buttonMode = true;
imageLoader.load(new URLRequest(xmlList[loaded].@path));
imageLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, imageLoaded);
preloader_mc.load_txt.text = String(loaded + 1) + " / " + xmlList.length() + " IMAGES LOADING";
}

imageLoaded fonksiyonunu tanımlıyoruz. Fonksiyon içerisinde yüklenen imajları imageHolderMC isimli MovieClip içerisine, imageHolderMC MovieClip’lerinide holderMC isimli MovieClip içerisine ekleyeceğiz. imageHolderMC MovieClip’lerini images isimli diziye ekledikten sonra loaded değişkenin değerini bu nesnelere isim olarak atayacağız. imageWidth değişkenine değer olarak yüklenen imajların genişliklerini atayacağız. imagePositions isimli dizi içerisinde de yüklenen her imajın x konumunu ekleyeceğiz. Slayt sola doğru hareket edeceği içinde -1 ile çarpıp negatif değere çevireceğiz.

İf.. else if koşullu ifadesi ile de yüklenen imajların sayısını kontrol edeceğiz. Eğer XML içerisindeki element sayısından küçükse loaded değişkeninin değerini artıracağız. Yeni bir imageLoader nesnesi tanımlayacağız ve yükleme işleminin bitişini kontrol etmek için bir olay dinleyici ekleyeceğiz. Eğer loaded değişkeninin değeri(yani yüklenen imaj sayısı) eleman sayısına eşitse buton olarak kullanacağımmız MovieClip’leri sahneye ekleyip geçişleri sağlayabilmek için olay dinleyicileri ekleyeceğiz. Selector isimli MovieClip’leri sahneye eklemek ve imajlara link verebilmek içinse bir döngü oluşturacağız. Oluşturduğumuz MovieClipleri selectorMC içerisinde ekleyip, butonlara tıklandığında ilgili imaja geçilebilmesini sağlamak için olay dinleyici ekleyeceğiz. Oluşturulan MovieClip’lerin isimlerini de döngünün içerisindeki i değişkeninden alacağız. İmages dizisi içerisindeki eleman sayısıda aynı olacağı için döngü içerisinde images dizisinin elemanlarına birer olay dinleyici ekleyerek sayfaların linklerini vereceğiz. Son olarakta preloader_mc isimli MovieClip’i sahneden kaldırıp Timer nesnesini çalıştıracağız.

Geçişileri sağlayabilmek için transitions() isminde bir fonksiyon oluşturacağız. Fonksiyon içerisinde ilk olarak Timer nesnesini resetleyip tekrar başlatacağız. Böylece süre dolmadan nextImaga, prevImage ya da selector butonlarından birine tıklandığında süreyi baştan başlatacağız. Sonrasında howImage degişkeninin değerini kontrol edeceğiz. Fonksiyon çalıştığında eğer xmlList nesnesinin eleman sayısına eşitse değerini sıfıra, eğer howImage değişkeninin değeri sıfırdan küçükse xmlList nesnesinin eleman sayısına eşitleyeceğiz. Böylece ilk veya son imaj görüntülenirken takılma olmayacak. Sonrasında da for döngüsü ile selector butonlarının içerisinde bulunan text alanının yazı rengini #999999 olarak değiştireceğiz. Döngünün çalışması bittikten sonra da howImage değişkeninin değerine göre hangi imaj görüntüleniyorsa selectors dizisinin ilgili elemanın içerisindeki text alanının yazı rengini #000000 olarak değiştireceğiz. Fonksiyon içerisinde son olarakta bir tween oluşturarak geçişlerin yapılmasını sağlayacağız. Tween animasyonunun başlangıç noktası holderMC isimli MovieClip’in x konumu, bitiş noktası ise imagePositions dizisinin içerisinde ilgili index numarasına sahip elemanın değeri olacak. Tween nesnesini oluşturmadan önce ilgili sınıfların import edilmesi gerekmektedir.

import fl.transitions.Tween;
import fl.transitions.easing.*;

Fonksiyonun aşağıdaki gibi olması gerekmektedir.

Son bölümde de Timer nesnesine bir olay dinleyici ekleyeceğiz ve daha öncesinde butonlara eklemiş olduğumuz olay dinleyicilerin fonksiyonlarını tanımlayacağız. nextImage butonuna tıklandığında veya Timer nesnesi çalıştığında howImage değişkenin değerini artırıp, prevImage butonuna tıklandığında azaltacağız. Selector butonlarından birine tıklandığında ise howImage değişkeninin değerini tıklanan butonun ismine göre değiştireceğiz. Tüm fonksiyonlarda değişkenin değerini değiştirdikrten sonra transitions() fonksiyonunu çağırarak geçişin yapılmasını sağlayacağız. transitions() fonksiyonun en altta kalacak şekilde aşağıdaki kod bloklarını yazalım.

transitionsTimer.addEventListener(TimerEvent.TIMER, startTransitions);

function startTransitions(e:TimerEvent)
{
howImage++;
transitions();
}

function nextImage(e:MouseEvent)
{
howImage++;
transitions();
}

function prevImage(e:MouseEvent)
{
howImage--;
transitions();
}

function selectImage(e:MouseEvent)
{
howImage = e.target.name;
transitions();
}

Son olarakta gotoURL fonksiyonunu tanımlayacağız. Hangi sayfanın açılacağını tıklanan imajın ismine göre xmlList nesnesinin ilgili elemanının içerisinde bulunan link niteliğini(attribute) kullanarak belirleyeceğiz. Eğer sayfanın aynı pencerede açılmasını istiyorsak “_blank” ifadesini “_self” olarak değştirebiliriz.

function gotoURL(e:MouseEvent)
{
navigateToURL(new URLRequest(xmlList[e.currentTarget.name].@link),"_blank");
}

Evet böylece rotatoru tamamlamış olduk. Kodların bitmiş halinin aşağıdaki gibi olması gerekmekdedir.

import flash.net.URLLoader;
import flash.net.URLRequest;
import flash.events.Event;
import flash.display.Loader;
import flash.display.MovieClip;
import flash.utils.Timer;
import flash.events.TimerEvent;
import fl.transitions.Tween;
import fl.transitions.easing.*;
import flash.events.MouseEvent;
import flash.ui.Mouse;

var xmlLoader:URLLoader=new URLLoader();
xmlLoader.load(new URLRequest("data/data.xml"));

var xmlData:XML;
var xmlList:XMLList;
var imageLoader:Loader;
var loaded:int = 0;
var howImage:int;
var imageWidth:int;

var maskMC:MovieClip=new MovieClip();
maskMC.graphics.beginFill(0x000000);
maskMC.graphics.drawRect(25,25,575,275);
maskMC.graphics.endFill();
addChild(maskMC);
var holderMC:MovieClip;
var imageHolderMC:MovieClip;
var selectorMC:MovieClip;

var nextButton:Next;
var prevButton:Previous;
var selector:Selector;

var imagePosition:Array=new Array();
var selectors:Array=new Array();
var images:Array=new Array();

var transitionsTimer:Timer = new Timer(1000 * 5);

xmlLoader.addEventListener(Event.COMPLETE, xmlLoaded);

function xmlLoaded(e:Event)
{
xmlData = new XML(e.target.data);
xmlList = new XMLList(xmlData.children());

imageLoader=new Loader();
holderMC=new MovieClip();
imageHolderMC=new MovieClip();
addChild(holderMC);
holderMC.x = 25;
holderMC.y = 25;
maskMC.cacheAsBitmap = true;
holderMC.cacheAsBitmap = true;
holderMC.mask = maskMC;

imageHolderMC.buttonMode = true;
imageLoader.load(new URLRequest(xmlList[loaded].@path));
imageLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, imageLoaded);
preloader_mc.load_txt.text = String(loaded + 1) + " / " + xmlList.length() + " IMAGES LOADING";
}

function imageLoaded(e:Event)
{
imageHolderMC=new MovieClip();
holderMC.addChild(imageHolderMC);
imageHolderMC.addChild(imageLoader);
imageHolderMC.x = loaded * imageLoader.content.width;
imageHolderMC.buttonMode = true;
images.push(imageHolderMC);
imageHolderMC.name=String(loaded);
imageWidth = imageLoader.content.width;
imagePosition.push(((imageWidth*loaded)*-1)+25);
preloader_mc.load_txt.text = String(loaded + 1) + " / " + xmlList.length() + " IMAGES LOADING";
setChildIndex(MovieClip(preloader_mc), numChildren-1);

if (loaded + 1 < xmlList.length())
{
loaded++;
imageLoader=new Loader();
imageLoader.load(new URLRequest(xmlList[loaded].@path));
imageLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, imageLoaded);
}
else if (loaded + 1 >= xmlList.length())
{
nextButton=new Next();
prevButton=new Previous();
addChild(nextButton);
addChild(prevButton);
nextButton.x = stage.stageWidth - 25;
nextButton.y = stage.stageHeight / 2;

prevButton.x = 25;
prevButton.y = stage.stageHeight / 2;
nextButton.buttonMode = true;
prevButton.buttonMode = true;
nextButton.mouseChildren = false;
prevButton.mouseChildren = false;

nextButton.addEventListener(MouseEvent.CLICK, nextImage);
prevButton.addEventListener(MouseEvent.CLICK, prevImage);

selectorMC=new MovieClip();

for (var i:int=0; i<xmlList.length(); i++)
{
selector=new Selector();
selectorMC.addChild(selector);
selector.selector_txt.text = String(i + 1);
selector.name = String(i);
selector.x = 25 * i;
selector.buttonMode = true;
selector.mouseChildren = false;
selectors.push(selector);
selector.addEventListener(MouseEvent.CLICK, selectImage);
images[i].addEventListener(MouseEvent.CLICK, gotoURL);
}

addChild(selectorMC);
selectorMC.x = stage.stageWidth / 2 - selectorMC.width / 2;
selectorMC.y = 305;
selectors[howImage].selector_txt.textColor = 0x000000;
removeChild(preloader_mc);
transitionsTimer.start();
}
}

transitionsTimer.addEventListener(TimerEvent.TIMER, startTransitions);

function startTransitions(e:TimerEvent)
{
howImage++;
transitions();
}

function nextImage(e:MouseEvent)
{
howImage++;
transitions();
}

function prevImage(e:MouseEvent)
{
howImage--;
transitions();
}

function selectImage(e:MouseEvent)
{
howImage = e.target.name;
transitions();
}

function gotoURL(e:MouseEvent)
{
navigateToURL(new URLRequest(xmlList[e.currentTarget.name].@link),"_blank");
}

function transitions()
{
transitionsTimer.reset();
transitionsTimer.start();

if (howImage >= xmlList.length())
{
howImage = 0;
}
else if (howImage<0)
{
howImage = xmlList.length() - 1;
}

for (var j:int=0; j<xmlList.length(); j++)
{
selectors[j].selector_txt.textColor = 0x999999;
}

selectors[howImage].selector_txt.textColor = 0x000000;

new Tween(holderMC,"x",Regular.easeOut,holderMC.x,imagePosition[howImage],1,true);
}

Örnek çalışma dosyasını indirebilmek için siteye üye olmanız gerekmektedir. Siteye üye olmak için tıklayın.

Flash Açılır Menü Yapımı – 2

Erol Demirer — Tue, 20 Apr 2010 10:31:11 +0000

Bu uygulamamızda bir öncekinden farklı bir yöntem ile açılır (Drop Down) menü oluşturacağız. Uygulamanın detaylı anlatımını videoda bulabilirsiniz.

Click here to view the embedded video.

Örnek çalışma dosyasını indirebilmek için siteye üye olmanız gerekmektedir. Siteye üye olmak için tıklayın.

ActionScript 3.0 Tween Sınıfı İle Animasyonlu Menü Yapımı

Erol Demirer — Sun, 28 Mar 2010 17:59:58 +0000

Bu uygulamamızda Tween sınıfını kullaranak animasyonlu bir menü yapacağız. Uygulama ile ilgili detaylı anlatımı videoda bulabilirsiniz.

Click here to view the embedded video.

Örnek çalışma dosyasını indirebilmek için siteye üye olmanız gerekmektedir. Siteye üye olmak için tıklayın.

ActionScript 3.0 XML Kullanımı

Erol Demirer — Mon, 01 Mar 2010 21:38:04 +0000

Click here to view the embedded video.

Örnek çalışma dosyasını indirebilmek için siteye üye olmanız gerekmektedir. Siteye üye olmak için tıklayın.

for Döngüsünü Kullanarak Sahneye Nesne Ekleme

Erol Demirer — Wed, 27 Jan 2010 20:56:37 +0000

Döngüleri kullanarak uygulamamızda kullandığımız nesneleri sahne üzerine istediğimiz sayıda ekleyebiliriz. Eklediğimiz nesnelerin x ve y konumlarını ister rastgele istersek belli arallıklarla belirleyebiliriz. Böylece bir nesneyi defalarca sahneye eklemek ile uğraşmak yerine bir kaç satır kod yazarak yapacağımız işlemi daha da kısaltabiliriz. Döngülerin en sevdiğim yanı da bu.

Bu uygulamamızda oluşturduğumuz bir nesneyi for döngüsünü kullanarak sahne üzerine 10 tane ekleyecceğiz. x ve y konumlarını da rastgele belirleyeceğiz. İlk olarak 600 x 400 piksel ebatlarında yeni bir döküman açalım ve kullanacağımız nesneyi oluşturup Movie Clip olarak sembole dönüüştürelim. Açılan pencerede Symbol Name kısmına “Nesne” yazalım. Sembole dönüştürdükten sonra Library panelinde sembolü seçip sağ tıklayalım ve açılan pencerede Linkage (Flasf CS4 sürümü için Properties > Advanced) seçeneğine tıklayıp Export for ActionScript seçeneğini işaretleyelim.

Bu seçeneği işaretledikten sonra üst kısımdaki kutucuklar aktif hale gelecektir. Class sekmesinde sembolu kaydederken vermiş olduğumuz isim, Base Class sekmesinde de flash.display.MovieClip yazacaktır. Bir şeyi değiştirmeden Ok tuşuna basalım. Eğer bir uyarı penceresi açılırsa Ok butonuna tıklayalım.

Böylece nesnemizi ActionSCript kütüphanesine yeni bir Class olarak kaydetmiş olduk. Sahne üzerinde duran nesneyi artık silebiliriz. Artık sahne üzerine ekleme işlemini kaydetmiş olduğumuz Nesne Class’ını kullanarak yapacağız. Class’ımızı oluşturduğumuza göre Actions panelini açıp aşağıdaki kodları yazabiliriz.

//Döngümüzü oluşturuyoruz
for (var i:Number=0; i<10; i++) {
//oluşturduğumuz Nesne Class'ına ait bir nesne tanımlıyoruz
var ornek_mc:Nesne = new Nesne();
//tanımladığımız nesnenin x ve y konumlarını belirtyoruz.
//Math.random() metodu ile bu değerleri rastgele olarak belirliyoruz.
//Sahne ölçülerimiz 600 x 400 piksel ebatlarındaydı eklediğimiz nesnelerin sahnenin dışına çıkmasını
//engellemek için oluşturduğumuz rastgele sayıları genişlik ve yükseklik değerlerinden
//100'er sayı küçük oluşturduk ve 50 ekledik. Böylece nesnelerin x konumu 50 - 550 piksel
// y konumları ise 50 - 350 piksel arasında değişecek
ornek_mc.x = 50 + Math.random() * 500;
ornek_mc.y = 50 + Math.random() * 300;
//addChild metodu ile nesneleri sahneye ekliyoruz.
addChild(ornek_mc);
}

Örnek çalışma dosyasını indirebilmek için siteye üye olmanız gerekmektedir. Siteye üye olmak için tıklayın.

for, for..in, for each..in Döngüleri ve Kullanımları

Erol Demirer — Sun, 24 Jan 2010 19:56:42 +0000

for döngüsü kod blooğunun belirli bir sayıda tekrar etmesini sağlamak için kullanılır. Mantığı oldukça basittir. Önce bir değişken tanımlarız, sonra bu değişkene bir koşul atarız son olarakta değişkenin değeri arttırılarak ya da azaltılarak kod bloğunun kaç kez çalışacağını belirleriz. Kullanımı ise şu şekildedir.

for (değişken:Number; koşul; değer değiştirme){

// çalışacak olan kod bloğu

}

Bir örnekle açıklayacak olursak;

for (var i:Number=0; i<;20; i++) {
trace("i değişkeninin değeri: " + i);
}

Örnekteki kod bloğu 20 defa çalışacaktır. Biraz açacak olursak, ilk olarak nümerik bir değişken tanımlıyor ve bu değişkene bir değer atıyoruz(var i:Number=0), sonra döngünün koşulunu belirliyoruz, yani değişkenin değerinin 20′den küçük olup olmadığını kontrol ediyoruz (i<20), son olarakta değişkenin değerini değiştirerek i değeri 20 den küçük olduğu sürece değeri 1 sayı arttırıyoruz. Son olarakta bloklar ( { } ) içerisine çalışacak olan kod bloğunu yazıyoruz. Örnekte çıktı ekranına i değeri yazdırılmıştır.

Döngüyü farklı bir şekilde kullanmak istersek:

var sehirler:Array = new Array("İstanbul", "Ankara", "İzmir", "Antalya", "Rize", "Kocaeli", "Edirne", "Trabzon", "Rize", "Mersin", "Bolu");

for (var i:Number = 0; i<sehirler.length; i++) {
trace(sehirler[i]);
}

Örnekte ilk olarak sehirler isimli bir dizi değişkeni tanımlanıyor ve bazı şehirlerin isimleri bu dizi değişkenine değer olarak atıyoruz. Sonrasında bir döngü oluşturuyoruz ve döngü koşulunu sehirler değişkeninin element sayısına göre belirliyoruz (i

for..in Döngüsü ve Kullanımı

Yukarıda for döngüsü ile yaptığımız işlemi for in dögüsünü kullanarak daha basit bir şekilde yapabiliriz. for in dögüsü dizi elemanlarını ya da objelerin özelliklerini almak için kullanılır ve bu işlemi oldukça kolaylaştırır. Yukarıdaki işlemi for in döngüsü ile yapacak olursak:

for (var i:String in sehirler) {
trace(sehirler[i]);
}

Döngünün çalışma mantığı aynı, dizi içerisindeki eleman sayısı kadar döngünün çalışması sağlanıyor. Çıktı ekranında iki kullanımı karşılaştırdığınızda alınan sonucun aynı olduğunu göreceksiniz. Şimdi de bir objenin özelliklerine ulaşmayı deneyelim. Mesela bir arabamız olsun ve bu arabanın tekerlekleri, motoru, vitesi, aynaları gibi özelliklerini listeleyelim. İlk önce araba objemizi tanımlayalım.

var araba:Object = new Object();

sonrasında da araba isimli objemizin özelliklerini belirleyelim.

araba.Marka = "Renault Clio";
araba.Model = "2009";
araba.Renk = "Siyah";
araba.Tekerlekler = "Bridgestone";
araba.Motor = "2.0 Benzinli";
araba.Vites = "Otomatik";
araba.Koltuklar = "Deri";
araba.Camlar = "Filmli";

Evet araba objemizin özelliklerini de belirledik. Şimdi sıra geldi for in döngüsünü kullanarak bu özellikleri listelemeye, objeye özellikleri verirken nokta ( . )operatörünü kullandık. Normalde program içerisinde bu özellikler yok, fakat bir objeye bir takım özellikler vermek istediğimizde obje ismini yazdıktan sonra nokta operatörünü kullanarak özellik adını yazabiliriz. Sonrasında da kullandığımız özellikler için değerleri tanımlarız. Döngümüzü oluşturup değerleri çıktı ekranına yazdıralım.

for (var ozellik:String in araba) {
trace(ozellik+": " + araba[ozellik]);
}

Evet kod yazma işlemi bittiğine göre uygulamamızı Ctrl + Enter tuşları ile test ettiğimizde çıktı ekranında yazanların şı şekilde olması gerekiyor.

Koltuklar: Deri
Motor: 2.0 Benzinli
Tekerlekler: Bridgestone
Model: 2009
Renk: Siyah
Marka: Renault Clio
Camlar: Filmli
Vites: Otomatik

Çıktı ekranında önce özellikler sonra da özelliklerin değerleri görüntülenecektir.

for each..in Döngüsü ve Kullanımı

for each in dögüsünün for in döngüsünden tek farkı objenin özellik ya da fonksiyonlarına direkt olarak ulaşmasıdır. Yukarıdaki örneği for each in döngüsü ile kullandığımızda döngüyü şu şekilde oluşturmamız gerekiyor.

for each (var ozellik:String in araba) {
trace(ozellik);
}

Çıktı ekranı:
Deri
2.0 Benzinli
Bridgestone
2009
Siyah
Renault Clio
Filmli
Otomatik

Görüldüğü gibi sadece özelliğin kendisini alıyor. Özelliklere direkt olarak ulaşabildiği içinde XML objelerinde daha fazla kullanılmaktadır. Nedeni ise tagleri almayıp taglerin içerisinde bulunan özellikleri almasıdır.

Döngüler

Erol Demirer — Sun, 24 Jan 2010 19:54:23 +0000

ActionScript içerisinde döngüler kod bloklarını belirli bir sayıda ya da bir koşul gerçekleşene kadar çalıştırmak için kullanılır. Örneğin sahne üzerine aynı film klibinden 20 adet eklemek ya da benzeri işlemleri gerçekleştirebilmek için döngüler oldukça kullanışlıdır ve yazılan kod satırları daha kısadır.

Koşullu ifadelerle karşılaştıracak olursak, koşullu ifadelerde kod satırları koşul gerçekleştiğinde çalışırken döngülerde kod satırları koşul gerçekleşene kadar çalışmaya devam eder. Koşul yerine getirildikten sonra kod satırlarının çalışması derleyici tarafından durdurulur.

ActionScript içerisinde yer alan döngüler aşağıda sıralanmıştır:

for
for..in
for each..in
while
do while

Kısaca özelliklerinden bahsedecek olursak for döngüsü bir kod bloğunu belli bir sayıda çalıştırmaya, for..in döngüsü objelerin özelliklerini almak, dizi elemanlarına ulaşmak için, for each..in objenin özellik ve fonksiyonlarına direk ulaşılmak istendiğinde (genellikle XML objelerinde), while döngüsü belli bir işlem meydana gelene kadar kod bloğunu çalışması istendiğinde kullanılır.

Döngülerin detaylı açıklama ve kullanımları ile ilgili bilgileri diğer makalelerde bulabilirsiniz.